//--------------------------
////Vendor System - by ClouD
//--------------------------

[ITEMDEF i_deed_vendor_pod]
NAME=Deed para vendor
ID=i_deed
TYPE=t_normal
VALUE=5000

ON=@Create
color=048d

on=@dclick
IF (<topobj.uid>!=<src>)
src.sysmessage @0481 A deed precisa estar com voce!
RETURN 1
ENDIF
IF (<src.account.tag0.vendedores>)
src.sysmessage @048d Voce ja tem 1 vendedor!
RETURN 1
ENDIF
IF (<src.flags>&statf_war)
src.flags &= ~statf_war
ENDIF
SERV.NEWITEM=i_gold
NEW.P=<SRC.P>
IF (<NEW.VENDORCHECK>)
SRC.SYSMESSAGE Ja existe outro vendor perto de voce.
RETURN 1
ENDIF
IF (0<uid.<src.region.uid>.more1>==<src>)
serv.newnpc=c_vendor_pod
new.p=<src.p>
FOR 10
try new.tag.last<eval <local._for>>=[nenhum]
ENDFOR
new.level=<src>
new.tag.fala=Sou o vendedor de <src.name>
new.exp=0
new.tag.itensvendidos=0
new.tag.current=0
new.title=Vendedor de <src.name>
new.tag.postoem=Posto em <rtime.day>/<rtime.month>/<rtime.year>
new.update
SERV.LOG @VENDORSYS: <SRC.NAME> (<src>) criou 1 vendor (<new>) em <SRC.P>
local.vendor_uid=<new>
new.sdialog d_vendor_owner_pod
serv.newitem=i_m_vendorfala,1,<local.vendor_uid>
new.timer=360
new.tag.player=<src>
serv.newitem=i_m_vendortimer,1,<local.vendor_uid>
new.timer=<HVAL 60*60*24*30>
src.account.tag.vendedores=1
remove
RETURN 1
ENDIF
IF !(<SRC.ISGM>) && (strcmpi(<SRC.REGION.NAME>,Mercado))
src.sysmessage @0483 Voce precisa por o vendor no mercado, ou na sua casa!
ELSE
serv.newnpc=c_vendor_pod
new.p=<src.p>
FOR 10
try new.tag.last<eval <local._for>>=[nenhum]
ENDFOR
new.level=<src>
new.tag.fala=Sou o vendedor de <src.name>
new.exp=0
new.tag.itensvendidos=0
new.tag.current=0
new.title=Vendedor de <src.name>
new.tag.postoem=Posto em <rtime.day>/<rtime.month>/<rtime.year>
new.update
SERV.LOG @VENDORSYS: <SRC.NAME> (<src>) criou 1 vendor (<new>) em <SRC.P>
local.vendor_uid=<new>
new.sdialog d_vendor_owner_pod
serv.newitem=i_m_vendorfala,1,<local.vendor_uid>
new.timer=360
new.tag.player=<src>
serv.newitem=i_m_vendortimer,1,<local.vendor_uid>
new.timer=<HVAL 60*60*24*30>
src.account.tag.vendedores=1
remove
ENDIF
RETURN 1

/////////Vendor////////////

[CHARDEF c_vendor_pod]
NAME=#NAMES_HUMANMALE
ID=c_man
CAN=mt_nonmover|MT_USEHANDS|MT_EQUIP|MT_FIRE_IMMUNE
ARMOR=200
TSPEECH=vendor_pod

on=@create
COLOR=colors_skin
STR=1
INT=0
DEX=0
FAME=0
FLAGS |= statf_invul
KARMA=0
ALLSKILLS=0.0
EQUIPHALO
tag.lucrototal=0
tag.money=0
tag.currentamount=0
MODMAXWEIGHT=5000000

ON=@NPCSEENEWPLAYER
IF (<src>==<level>)
say @0ad Ola mestre <src.name>
ELIF (<findid.i_m_falas>)
say @<tag.name.hue> <tag.fala>
ENDIF

on=@npcrestock
ITEM=random_male_hair
color=36
ITEM=i_bagdeitens
ITEM=random_hats
ITEM=random_footwear
ITEM=random_male_pants
ITEM=random_over_armor
ITEM=i_lantern
MOREY=1
TIMER=-1
ITEM=i_m_falas
TIMER=-1

on=@Click
IF (<findid.i_m_vendorfala>) && (<findid.i_m_vendorfala.timer>!=-1)
message [ocupado]
ENDIF
message @<tag.name.hue> <name> (Itens: <eval <exp>>)
RETURN 1

On=@dclick
IF !(<src.isgm>)
RETURN 1
ENDIF

ON=@DEATH
hits=<str>
action -1
RETURN 1

ON=@GetHit
RETURN 1

on=@hittry
RETURN 1

ON=@Attack
RETURN 1

ON=@UserWarMode
flags &= ~statf_war
RETURN 1

on=@spelleffect
RETURN 1

ON=@CallGuards
RETURN 1

//////////////////

[SPEECH vendor_pod]
ON=buy
on=comprar
IF !(<src.flags>&statf_dead)
IF (<distance> > 2)
RETURN 1
ENDIF
IF !(<uid.<level>.isplayer>)
src.sysmessage Este Vendor nao tinha dono e foi deletado.
remove
RETURN 1
ENDIF
IF (<f_players_perto>)
src.sysmessage @0481 O vendor ja esta sendo utilizado, aguarde um pouco.
RETURN 1
ENDIF
IF (<src.memoryfindtype.memory_gumprecord>)
src.sysmessage @0481 Feche o menu antes!
RETURN 1
ENDIF
IF (<src>!=<level>)
src.sysmessage @0483 Bem vindo ao menu de compras de <uid.<level>.name>, escolha o item.
tag.itemlist2=0
tag.currentamount=0
sdialog d_vendor_podprinc
serv.newitem=i_m_vendorfala,1,<uid>
new.tag.player=<src>
new.timer=360
ELIF (<src>==<level>)
say @0488 Voce quer comprar de voce mesmo!?
ENDIF
ENDIF

ON=stock
on=estocar
IF !(<src.flags>&statf_dead)
IF (<src.isgm>) && !(<findid.i_m_vendorfala>)
serv.newitem=i_m_vendorfala,1,<uid>
new.tag.player=<src>
new.timer=360
tag.current=1
sdialog d_vendor_owner_pod
RETURN 1
ENDIF
IF (<distance> > 2)
RETURN 1
ENDIF
IF (<src.memoryfindtype.memory_gumprecord>)
src.sysmessage @0481 Feche o menu antes!
RETURN 1
ENDIF
IF (<src.findid.i_memory_ivendor>)
src.sysmessage Voce ja esta usando seu vendor.
RETURN 1
ENDIF
IF (<src>!=<level>)
say @0481 Voce nao e o dono!
RETURN 1
ENDIF
IF (<src>==<level>)
findid.i_m_vendortimer.timer=<HVAL 60*60*24*30>
IF (<findid.i_m_vendorfala>) 
IF !(<uid.<findid.i_m_vendorfala.tag.player>.isonline>)
findid.i_m_vendorfala.remove
ELIF (<uid.<findid.i_m_vendorfala.tag.player>.isonline>) && (<findid.i_m_vendorfala.tag.player>!=<src>)
try uid.<findid.i_m_vendorfala.tag.player>.sysmessage <src.name> quer usar o vendor dele, com licenca.
findid.i_m_vendorfala.timerd 1
serv.newitem=i_m_vendorfala,1,<uid>
new.tag.player=<src>
new.timer=360
ENDIF
ENDIF
tag.current=1
tag.itemlist2=0
sdialog d_vendor_owner_pod
serv.newitem=i_m_vendorfala,1,<uid>
new.tag.player=<src>
new.timer=<HVAL 60*6>
say @0481 Ola mestre!
ENDIF
ENDIF

on=venha
IF !(<src.flags>&statf_dead)
IF (<src>!=<level>)
say @0481 Voce nao e o dono!
RETURN 1
ENDIF
SERV.NEWITEM i_gold
NEW.P=<SRC.P>
NEW.LINK=<uid>
IF (<NEW.VENDORCHECK>)
SRC.SYSMESSAGE Ja existe outro vendor perto de voce.
NEW.REMOVE
RETURN 1
ENDIF
IF (<uid.<src.region.uid>.more1>==<src>) && (<src>==<level>)
p=<src.p>
NEW.REMOVE
UPDATE
RETURN 1
ENDIF
IF (<src>==<level>) && (strcmpi(<SRC.REGION.NAME>,Mercado))
say @048d Eu so posso ficar na sua casa, ou no mercado!
ELIF (<src>==<level>) && !(strcmpi(<SRC.REGION.NAME>,Mercado))
p=<src.p>
NEW.REMOVE
update
ENDIF
ENDIF

on=ajuda
src.weblink <serv.URL>

///////////////////////

[DIALOG d_vendor_owner_pod]
140, 0
src.closealldialogs
PAGE 0
resizepic 55 87 3500 300 335
dtext 88 132 46 Pegar Itens de Volta
button 70 135 2117 2118 1 0 1
button 70 165 2117 2118 1 0 2
dtext 88 163 46 Abrir seu Banco
button 70 195 2117 2118 1 0 3
dtext 88 191 46 Adicionar Item
button 70 225 2117 2118 1 0 4
dtext 88 220 46 Remover/Editar Item
button 70 255 2117 2118 1 0 5
dtext 88 252 46 Converter Vendor para Deed (5k)
button 229 370 4005 4006 1 0 6
dtext 160 390 270 Caracteristicas do Vendor
dtext 107 99 1345 Vendor System
dtext 88 300 59 Itens a venda: <eval <exp>>
dtext 88 320 59 Itens vendidos: <eval <tag.itensvendidos>>
dtext 88 340 59 Lucro total: <eval <tag.lucrototal>>gps
button 70 283 2117 2118 1 0 7
dtext 88 280 46 Sacar dinheiro (<eval <tag.money>>gps)

[DIALOG d_vendor_owner_pod BUTTON]
on=0
findid.i_m_vendorfala.remove

on=1
IF (<distance> > 5)
src.sysmessage @0480 Voce esta longe demais do seu vendor.
findid.i_m_vendorfala.remove
RETURN 1
ENDIF
IF !(<exp>)
src.sysmessage Seu vendor nao tem itens a venda!
sdialog d_vendor_owner_pod
RETURN 1
ENDIF
local.flags=<src.region.flags>
local.lastp=<src.p>
src.region.flags=0
src.p=1,1
IF (<exp>)
serv.newitem=i_backpack,1,<src.findlayer.29>
new.name=Vendor Bag
new.color=39
f_retirar_itens <new>
ENDIF
exp=0
src.sysmessage @0483 Itens postos em seu bank!
findid.i_m_vendorfala.remove
src.p=<local.lastp>
src.region.flags=<local.flags>
src.fix

on=2
IF (<distance> > 5)
src.sysmessage @0480 Voce esta longe demais do seu vendor.
findid.i_m_vendorfala.remove
ELSE
sdialog d_vendor_owner_pod
src.bankself
ENDIF

on=3
IF (<distance> > 5)
src.sysmessage @0480 Voce esta longe demais do seu vendor.
findid.i_m_vendorfala.remove
ELSE
src.findid.i_loot.remove
serv.newitem=i_memory_ivendor
new.link=<uid>
new.equip
new.timer=60
ENDIF

on=4
IF (<distance> > 5)
src.sysmessage @0480 Voce esta longe demais do seu vendor.
findid.i_m_vendorfala.remove
RETURN 1
ENDIF
IF !(<exp>)
src.sysmessage @0480 Nao ha itens a serem vendidos!
sdialog d_vendor_owner_pod
ELSE
sdialog d_remover_item1
ENDIF

on=5
IF (<distance> > 5)
src.sysmessage @0480 Voce esta longe demais do seu vendor.
findid.i_m_vendorfala.remove
RETURN 1
ENDIF
IF (<src.totalgold_2> < 5000)
src.sysmessage @048d Voce nao tem dinheiro suficiente.
sdialog d_vendor_owner_pod
RETURN 1
ENDIF
IF (<tag.money>)
local.tax=<HVAL (<tag.money>*5)/100>
tag.money -= <local.tax>
addgold <tag.money> <src.findlayer.29>
tag.money=0
ENDIF
local.lastp=<src.p>
local.flags=<src.region.flags>
src.region.flags=0
src.p=1,1
src.consumegold 5000
IF (<exp>)
serv.newitem=i_backpack,1,<src.findlayer.29>
new.name=Vendor Bag
new.color=39
f_retirar_itens <new>
src.sysmessage @0483 Itens postos em seu bank e vendor deletado!
ENDIF
serv.newitem=i_deed_vendor_pod
new.bounce
SERV.LOG @VENDORSYS: <SRC.NAME> (<src>) redeedou 1 vendor (<name> [<UID>]) em <P>
src.account.tag.vendedores
src.p=<local.lastp>
src.region.flags=<local.flags>
src.fix
remove

on=6
IF (<distance> > 5)
src.sysmessage @0480 Voce esta longe demais do seu vendor.
findid.i_m_vendorfala.remove
ELSE
sdialog d_caracteristicas_vendor
ENDIF

on=7
IF !(<tag0.money>)
sdialog d_vendor_owner_pod
ELSE
local.tax=<HVAL (<tag.money>*5)/100>
tag.money -= <local.tax>
src.sysmessage O vendor pegou 5% (<eval <local.tax>>) dos lucros pelos seus trabalhos.
src.sysmessage Dinheiro depositado no seu Bank.
addgold <tag.money> <src.findlayer.29>
tag.money=0
sdialog d_vendor_owner_pod
ENDIF

//////////////

[itemdef i_memory_ivendor]
NAME=Item Selector
ID=i_handr_1
TYPE=t_eq_script
layer=layer_special

on=@create
attr=attr_invis|attr_decay

on=@equip
target @0483 Escolha o item!

on=@targon_cancel
link.findid.i_m_vendorfala.remove
remove

ON=@targon_char
src.sysmessage Isto nao e um item!
link.findid.i_m_vendorfala.remove
remove
RETURN 1

ON=@Targon_Ground
src.sysmessage Isto nao e um item!
link.findid.i_m_vendorfala.remove
remove
RETURN 1

on=@targon_item
IF (<link.distance> > 4)
src.sysmessage @0480 O Vendor esta longe demais para pegar seu item.
link.findid.i_m_vendorfala.remove
ELIF (<src.targ.cont>==<src>)
src.sysmessage O item nao pode estar equipado em voce.
link.findid.i_m_vendorfala.remove
ELIF (<src.targ.topobj.uid>!=<src>)
src.sysmessage O item precisa estar com voce, ou no seu banco.
link.findid.i_m_vendorfala.remove
ELIF (<src.targ.baseid>==i_gold) || (<src.targ.tag0.novendor>)
src.sysmessage @0488 Item invalido.
link.findid.i_m_vendorfala.remove
ELIF (<link.exp> > 59)
src.sysmessage Voce ja tem 60 itens no vendor
link.findid.i_m_vendorfala.remove
ELIF (<src.targ.topobj.uid>==<src>) && !(<link.tag0.iuid<eval <link.exp>+1>>)
local.typevend=<src.targ.type>
local.corvend=<src.targ.color>
local.morevend=<src.targ.more1>
src.targ.timer -1
src.targ.more1=<HVAL {1 999999}>
src.targ.color=-1
src.targ.type=t_script
src.targ.cont=<link.findlayer.21>
try link.tag.iuid<eval <link.exp>+1>=<src.targ>
try link.tag.preco<eval <link.exp>+1>=<src.targ.value>
link.exp += 1
src.targ.type=<local.typevend>
src.targ.color=<local.corvend>
src.targ.more1=<local.morevend>
link.tag.current=<link.exp>
link.sdialog d_vendor_price1
link.findid.i_m_vendorfala.remove
ENDIF
remove
RETURN 1

on=@timer
remove
RETURN 1

//////////////////////

[DIALOG d_vendor_price1]
10,30
noclose
src.closealldialogs
page 0
resizepic 185 190 3600 340 140
resizepic 195 200 3500 320 120
dtext 230 210 0 Coloque o preco para <uid.<tag0.iuid<eval <tag.current>>>.name>
dtextentry 270 250 300 25 55 0 <eval <tag.preco<eval <tag0.current>>>>
button 250 250 5224 5003 1 0 1

[DIALOG d_vendor_price1 BUTTON]
on=0
findid.i_m_vendorfala.remove

on=1
IF (<distance> > 5)
src.sysmessage @0480 Voce esta longe demais do seu vendor.
findid.i_m_vendorfala.remove
ELIF (0<ISEMPTY <argtxt[0]>>)
src.sysmessage @048d O valor deve ter no minimo 1 letra!
sdialog d_vendor_price1
ELIF (0<ISBADSTR <ARGTXT[0]>>) || (STRMATCH(*[a-z]*,<ARGTXT[0]>))
src.sysmessage Preco invalido.
sdialog d_vendor_price1
ELIF STRMATCH(0*,<ARGTXT[0]>)
src.sysmessage @0481 Nao se pode por 0 no inicio do valor!
sdialog d_vendor_price1
ELIF !(strcmpi(<argtxt[0]>,0))
src.sysmessage @0481 Esse valor nao e permitido!
sdialog d_vendor_price1
ELSE
try tag.preco<eval <tag0.current>>=<strsub 0 9 <argtxt[0]>>
tag.current=1
sdialog d_vendor_owner_pod
ENDIF

//////////////Remover itens//////////////////

[DIALOG d_remover_item1]
210, 100
src.closealldialogs
PAGE 0
resizepic 15 70 3500 390 235
LOCAL.TMP=<OBJ>
OBJ=<tag.iuid<eval <tag.current>>>
LOCAL.COLOR=<OBJ.COLOR>
IF (<OBJ.COLOR> >= 0775)
LOCAL.COLOR -= 1
ENDIF
OBJ=<LOCAL.TMP>
tilepichue 75 80 <uid.<tag.iuid<eval <tag.current>>>.id> <eval <local.color>>
dtext 101 128 1152 <uid.<tag.iuid<eval <tag.current>>>.name>
dtext 49 128 102 Nome:
dtext 100 155 1152 <uid.<tag.iuid<eval <tag.current>>>.amount>
dtext 49 154 102 Quant.:
dtext 49 181 102 Preco:
dtext 99 182 1152 <eval <tag.preco<eval <tag.current>>>>
dtext 49 210 102 Descricao:
dcroppedtext 117 210 110 110 1152 <QVAL <ISEMPTY <tag.desc<eval <tag.current>>>> ? ...:<tag.desc<eval <tag.current>>>>
button 63 250 249 248 1 0 1
dtext 67 272 32 Remover
button 341 251 4005 4006 1 0 2
dtext 330 272 32 Proximo
button 242 251 4014 4015 1 0 3
dtext 233 272 32 Voltar
button 242 161 4005 4006 1 0 4
dtext 276 161 88 Editar Preco
dtext 276 90 55 Item <eval <tag0.current>>
button 30 213 01519 01519 1 0 5
IF (<exp> > 9)
button 341 221 4005 4006 1 0 6
button 242 221 4014 4015 1 0 7
ENDIF

[DIALOG d_remover_item1 BUTTON]
on=0
findid.i_m_vendorfala.remove

on=1
IF (<distance> > 5)
src.sysmessage @0480 Voce esta longe demais do seu vendor.
findid.i_m_vendorfala.remove
ELIF !(0<tag.iuid<eval <tag.current>>>)
src.sysmessage Nao ha nada nesse slot!
findid.i_m_vendorfala.remove
ELSE
local.lastp=<src.p>
local.flags=<src.region.flags>
src.p=1,1
try tag.preco<eval <tag.current>>
try uid.<tag.iuid<eval <tag.current>>>.cont=<src.findlayer.29>
try tag.iuid<eval <tag.current>>
try tag.desc<eval <tag.current>>
tag.current -= 1
src.sysmessage Item posto em seu bank.
f_ajeitar_itens
exp -= 1
findid.i_m_vendorfala.remove
src.bankself
src.p=<local.lastp>
src.region.flags=<local.flags>
src.updatex
ENDIF

on=2
IF !(0<tag.iuid<eval <tag.current>+1>>)
tag.current=1
sdialog d_remover_item1
ELIF (<distance> > 5)
src.sysmessage @0480 Voce esta longe demais do seu vendor.
findid.i_m_vendorfala.remove
ELSE
tag.current += 1
sdialog d_remover_item1
ENDIF

on=3
IF (<distance> > 5)
src.sysmessage @0480 Voce esta longe demais do seu vendor.
findid.i_m_vendorfala.remove
RETURN 1
ENDIF
IF (<tag.current> > 1)
tag.current -= 1
sdialog d_remover_item1
ELSE
tag.current=<exp>
sdialog d_remover_item1
ENDIF

on=4
IF (<distance> > 5)
src.sysmessage @0480 Voce esta longe demais do seu vendor.
findid.i_m_vendorfala.remove
RETURN 1
ENDIF
IF !(0<tag.iuid<eval <tag.current>>>)
src.sysmessage @036 Nao ha itens no slot <eval <tag.current>>!
sdialog d_vendor_owner_pod
ELSE
sdialog d_vendor_price1
ENDIF

on=5
IF !(0<tag.iuid<eval <tag.current>>>)
src.sysmessage @036 Nao ha itens no slot <eval <tag0.current>>!
sdialog d_vendor_owner_pod
ELSE
tag.algarismo=<HVAL <tag0.current>>
sdialog d_mudardesc1
ENDIF

on=6
IF !(0<tag.iuid<eval <tag.current>+10>>)
tag.current=<exp>
sdialog d_remover_item1
ELIF (<distance> > 5)
src.sysmessage @0480 Voce esta longe demais do seu vendor.
findid.i_m_vendorfala.remove
ELSE
tag.current += 10
sdialog d_remover_item1
ENDIF

on=7
IF (<distance> > 5)
src.sysmessage @0480 Voce esta longe demais do seu vendor.
findid.i_m_vendorfala.remove
RETURN 1
ENDIF
IF (0<tag.iuid<eval <tag.current>-10>> < 1)
tag.current=1
sdialog d_remover_item1
ELIF (<tag.current> > 10)
tag.current -= 10
sdialog d_remover_item1
ELIF (<tag.current>==1)
tag.current=<exp>
sdialog d_remover_item1
ENDIF

//////////////////Caracteristicas Vendor///////////////

[DIALOG d_caracteristicas_vendor]
170, 55
src.closealldialogs
PAGE 0
resizepic 39 84 2600 330 270
dtext 114 98 55 Caracteristicas do vendor
dtext 75 130 1152 Nome: <name>
dtext 75 159 1152 <tag.postoem>
dtext 75 187 1152 Falas <QVAL <FINDID.i_m_falas> ? Ligadas : Desligadas>
dtext 75 231 1152 Cor do nome:
dtext 168 231 <eval <tag.name.hue>> COR
dtext 75 207 1152 Fala:
dtext 110 207 1152 <tag.fala>
button 58 133 2117 2118 1 0 1
button 58 209 2117 2118 1 0 2
button 58 233 2117 2118 1 0 3
button 55 275 4005 4006 1 0 4
dtext 85 276 66 Ultimas Vendas
button 58 253 2117 2118 1 0 7
dtext 78 250 1152 Vestir o vendor como voce
button 58 187 2117 2118 1 0 5
button 90 308 4016 4015 1 0 6
dtext 120 310 1152 Voltar

[DIALOG d_caracteristicas_vendor BUTTON]
on=0
findid.i_m_vendorfala.remove

on=1
IF (<distance> > 5)
src.sysmessage @0480 Voce esta longe demais do seu vendor.
findid.i_m_vendorfala.remove
ELSE
sdialog d_mudarnome_vendor
ENDIF

on=2
IF (<distance> > 5)
src.sysmessage @0480 Voce esta longe demais do seu vendor.
findid.i_m_vendorfala.remove
ELSE
sdialog d_mudarfala_vendor
ENDIF

on=3
IF (<distance> > 5)
src.sysmessage @0480 Voce esta longe demais do seu vendor.
findid.i_m_vendorfala.remove
ELSE
sdialog d_mudarcor_vendor
ENDIF

on=4
IF (<distance> > 5)
src.sysmessage @0480 Voce esta longe demais do seu vendor.
findid.i_m_vendorfala.remove
ELSE
sdialog d_lastvendor
ENDIF

on=5
IF (<distance> > 5)
src.sysmessage @0480 Voce esta longe demais do seu vendor.
findid.i_m_vendorfala.remove
RETURN 1
ENDIF
IF (<findid.i_m_falas>)
findid.i_m_falas.remove
sdialog d_caracteristicas_vendor
ELIF !(<findid.i_m_falas>)
serv.newitem=i_m_falas,1,<uid>
sdialog d_caracteristicas_vendor
ENDIF

on=6
sdialog d_vendor_owner_pod

on=7
FOR 24
IF (<local._for>!=9) && (<local._for>!=11) && (<local._for>!=15) && (<local._for>!=18) && (<local._for>!=21)
TRY FINDLAYER.<EVAL <LOCAL._FOR>>.REMOVE
IF (<SRC.FINDLAYER.<EVAL <LOCAL._FOR>>>)
SERV.NEWITEM=<SRC.FINDLAYER.<EVAL <LOCAL._FOR>>.DISPID>,1,<UID>
NEW.COLOR=<SRC.FINDLAYER.<EVAL <LOCAL._FOR>>.COLOR>
NEW.NAME=<SRC.FINDLAYER.<EVAL <LOCAL._FOR>>.NAME>
ENDIF
ENDIF
ENDFOR
color=<src.color>
oskin=<src.oskin>
sdialog d_caracteristicas_vendor 1

//////////////////////

[DIALOG d_mudarnome_vendor]
10,30
src.closealldialogs
page 0
resizepic 195 200 2620 320 120
dtext 250 210 77 Coloque o nome do seu vendor
dtextentry 270 250 300 25 99 0 <name>
button 250 250 5224 5003 1 0 1

[DIALOG d_mudarnome_vendor BUTTON]
on=0
IF (<distance> > 5)
src.sysmessage @0480 Voce esta longe demais do seu vendor.
findid.i_m_vendorfala.remove
ELSE
sdialog d_caracteristicas_vendor
ENDIF

on=1
IF (<distance> > 5)
src.sysmessage @0480 Voce esta longe demais do seu vendor.
findid.i_m_vendorfala.remove
ELIF (0<ISEMPTY <argtxt[0]>>)
src.sysmessage @048d O nome deve ter no minimo 1 letra!
sdialog d_mudarnome_vendor
ELIF (0<ISBADSTR <ARGTXT[0]>>) || (STRMATCH(*[0-9]*,<ARGTXT[0]>))
src.sysmessage Nome invalido.
sdialog d_mudarnome_vendor
ELIF (STRMATCH(Seer*,<ARGTXT[0]>))
src.sysmessage @0481 Nao e permitido usar Seer no nome!
findid.i_m_vendorfala.remove
ELIF (STRMATCH(Conselour*,<ARGTXT[0]>))
src.sysmessage @0481 Nao e permitido usar Conselour no nome!
findid.i_m_vendorfala.remove
ELIF (STRMATCH(Admin*,<ARGTXT[0]>))
src.sysmessage @0481 Nao e permitido usar Admin no nome!
findid.i_m_vendorfala.remove
ELIF (STRMATCH(Staff*,<ARGTXT[0]>))
src.sysmessage @0481 Nao e permitido usar Staff no nome!
findid.i_m_vendorfala.remove
ELIF (STRMATCH(GM*,<ARGTXT[0]>))
src.sysmessage @0481 Nao e permitido usar GM no nome!
findid.i_m_vendorfala.remove
ELIF (STRMATCH(@*,<ARGTXT[0]>))
src.sysmessage @0481 Nao e permitido usar @ no nome!
findid.i_m_vendorfala.remove
ELIF (STRMATCH(EOF*,<ARGTXT[0]>))
src.sysmessage @0481 Esse nome nao e permitido!
findid.i_m_vendorfala.remove
ELIF !(strcmpi(<argtxt[0]>,@-1))
src.sysmessage @0481 Esse nome nao e permitido!
findid.i_m_vendorfala.remove
ELIF !(strcmpi(<argtxt[0]>,EOF))
src.sysmessage @0481 Esse nome nao e permitido!
findid.i_m_vendorfala.remove
ELSE
name=<strsub 0 20 <argtxt[0]>>
sdialog d_caracteristicas_vendor
ENDIF

//////////////////////

[DIALOG d_mudarfala_vendor]
10,30
src.closealldialogs
page 0
resizepic 195 200 2620 320 120
dtext 250 210 77 Coloque a fala do seu vendor
dtextentry 270 250 300 25 99 0 <tag.fala>
button 250 250 5224 5003 1 0 1

[DIALOG d_mudarfala_vendor BUTTON]
on=0
IF (<distance> > 5)
src.sysmessage @0480 Voce esta longe demais do seu vendor.
findid.i_m_vendorfala.remove
ELSE
sdialog d_caracteristicas_vendor
ENDIF

on=1
IF (<distance> > 5)
src.sysmessage @0480 Voce esta longe demais do seu vendor.
findid.i_m_vendorfala.remove
ELIF (0<ISEMPTY <argtxt[0]>>)
src.sysmessage @048d A fala deve ter no minimo 1 letra!
findid.i_m_vendorfala.remove
ELIF (<ISBADSTR <ARGTXT[0]>>) || (STRMATCH(*[0-9]*,<ARGTXT[0]>))
src.sysmessage Fala invalida.
sdialog d_mudarfala_vendor
ELIF (STRMATCH(Seer*,<ARGTXT[0]>))
src.sysmessage @0481 Nao e permitido usar Seer na fala!
findid.i_m_vendorfala.remove
ELIF (STRMATCH(Conselour*,<ARGTXT[0]>))
src.sysmessage @0481 Nao e permitido usar Conselour na fala!
findid.i_m_vendorfala.remove
ELIF (STRMATCH(Admin*,<ARGTXT[0]>))
src.sysmessage @0481 Nao e permitido usar Admin na fala!
findid.i_m_vendorfala.remove
ELIF (STRMATCH(Staff*,<ARGTXT[0]>))
src.sysmessage @0481 Nao e permitido usar Staff na fala!
findid.i_m_vendorfala.remove
ELIF (STRMATCH(GM*,<ARGTXT[0]>))
src.sysmessage @0481 Nao e permitido usar GM na fala!
findid.i_m_vendorfala.remove
ELIF (STRMATCH(@*,<ARGTXT[0]>))
src.sysmessage @0481 Nao e permitido usar @ na fala!
findid.i_m_vendorfala.remove
ELIF (STRMATCH(EOF*,<ARGTXT[0]>))
src.sysmessage @0481 Essa fala nao e permitida!
findid.i_m_vendorfala.remove
ELIF !(strcmpi(<argtxt[0]>,@-1))
src.sysmessage @0481 Essa fala nao e permitida!
findid.i_m_vendorfala.remove
ELIF !(strcmpi(<argtxt[0]>,EOF))
src.sysmessage @0481 Essa fala nao e permitida!
findid.i_m_vendorfala.remove
ELSE
tag.fala=<strsub 0 30 <argtxt[0]>>
sdialog d_caracteristicas_vendor
ENDIF

///////////////////////////

[DIALOG d_mudarcor_vendor]
0, 0
src.closealldialogs
PAGE 0
gumppic 110 122 7
button 205 153 210 211 1 0 1
dtext 229 153 1152 Branca
button 206 183 210 211 1 0 2
dtext 229 182 152 Amarela
button 207 214 210 211 1 0 3
dtext 231 214 162 Verde
button 208 246 210 211 1 0 4
dtext 233 246 32 Vermelha
button 209 275 210 211 1 0 5
dtext 235 275 102 Azul
dtext 174 124 1350 Cor do nome do vendor

[DIALOG d_mudarcor_vendor BUTTON]
on=0
IF (<distance> > 5)
src.sysmessage @0480 Voce esta longe demais do seu vendor.
findid.i_m_vendorfala.remove
ELSE
sdialog d_caracteristicas_vendor
ENDIF

on=1
IF (<distance> > 5)
src.sysmessage @0480 Voce esta longe demais do seu vendor.
findid.i_m_vendorfala.remove
ELSE
tag.name.hue=0481
sdialog d_caracteristicas_vendor
ENDIF

on=2
IF (<distance> > 5)
src.sysmessage @0480 Voce esta longe demais do seu vendor.
findid.i_m_vendorfala.remove
ELSE
tag.name.hue=55
sdialog d_caracteristicas_vendor
ENDIF

on=3
IF (<distance> > 5)
src.sysmessage @0480 Voce esta longe demais do seu vendor.
findid.i_m_vendorfala.remove
ELSE
tag.name.hue=0ad
sdialog d_caracteristicas_vendor
ENDIF

on=4
IF (<distance> > 5)
src.sysmessage @0480 Voce esta longe demais do seu vendor.
findid.i_m_vendorfala.remove
ELSE
tag.name.hue=0483
sdialog d_caracteristicas_vendor
ENDIF

on=5
IF (<distance> > 5)
src.sysmessage @0480 Voce esta longe demais do seu vendor.
findid.i_m_vendorfala.remove
ELSE
tag.name.hue=88
sdialog d_caracteristicas_vendor
ENDIF

////////////Descrição///////////

[DIALOG d_mudardesc1]
10,30
src.closealldialogs
page 0
resizepic 195 200 2620 320 120
dtext 250 210 77 Coloque a descricao de <uid.<tag.iuid<eval <tag0.algarismo>>>.name>
dtextentry 220 250 640 85 99 0 <QVAL <ISEMPTY <tag.desc<eval <tag0.algarismo>>>> ? ...:<tag.desc<eval <tag0.algarismo>>>>
button 200 250 5224 5003 1 0 1

[DIALOG d_mudardesc1 BUTTON]
on=0
IF (<distance> > 5)
src.sysmessage @0480 Voce esta longe demais do seu vendor.
findid.i_m_vendorfala.remove
ELSE
sdialog d_vendor_owner_pod
ENDIF

on=1
IF (<distance> > 5)
src.sysmessage @0480 Voce esta longe demais do seu vendor.
findid.i_m_vendorfala.remove
ELIF (0<ISEMPTY <argtxt[0]>>)
src.sysmessage @048d A descricao deve ter no minimo 1 letra!
sdialog d_mudardesc1
ELIF (0<ISBADSTR <ARGTXT[0]>>) || (STRMATCH(*[0-9]*,<ARGTXT[0]>))
src.sysmessage Descricao invalida.
sdialog d_mudardesc1
ELIF (STRMATCH(EOF*,<ARGTXT[0]>))
src.sysmessage Descricao invalida.
sdialog d_mudardesc1
ELIF !(strcmpi(<argtxt[0]>,EOF))
src.sysmessage Descricao invalida.
sdialog d_mudardesc1
ELSE
try tag.desc<eval <tag0.algarismo>>=<argtxt[0]> .
sdialog d_remover_item1
ENDIF

///////////////Comprador///////////////

[DIALOG d_vendor_podprinc]
210, 100
src.closealldialogs
PAGE 1
resizepic 20 30 3500 395 270
CHECKERTRANS 20 30 395 270
tilepic 260 90 3823
tilepic 280 90 3823
tilepic 270 105 3823
tilepic 250 105 3826
tilepic 290 105 3826
dtext 49 80 0ad Nome:
dtext 93 80 1152 <name>
dtext 49 110 0ad Dono:
dtext 93 110 1152 <uid.<level>.name>
dtext 49 140 0ad <tag.postoem>
dtext 49 170 0ad Itens a venda:
dtext 153 170 1152 <eval <exp>>
dtext 49 200 0ad Itens vendidos:
dtext 153 200 1152 <eval <tag.itensvendidos>>
IF (<exp>)
button 222 261 4005 4006 1 0 1
dtext 252 260 39 Ver itens a venda
ENDIF
dtext 49 230 0ad Lucro total:
dtext 133 230 1152 <eval <tag.lucrototal>>
dtext 130 40 036 Vendor System
button 50 260 093A 0939 0 2 2
dtext 65 255 2010 Ultimas Vendas
IF (<exp>)
button 222 231 4005 4006 0 3 4
dtext 252 230 39 Lista Rapida
ENDIF

PAGE 2
resizepic 0 0 3500 300 270
CHECKERTRANS 0 0 300 270
dtext 100 10 036 Ultimas Vendas
FOR 10
dtext 40 <eval (<local._for>*20)+10> 1152 <tag0.last<eval <local._for>>>
ENDFOR
button 200 235 4016 4015 0 1 3

PAGE 3
resizepic 0 0 3500 300 270
CHECKERTRANS 0 0 300 270
dtext 100 10 036 Lista Rapida
FOR 10
local.blah=<HVAL <TAG0.ITEMLIST2>+<LOCAL._FOR>>
IF (<TAG0.IUID<EVAL <LOCAL.BLAH>>>)
dtext 50 <eval (<local._for>*20)+10> 1152 <UID.<TAG0.IUID<EVAL <LOCAL.BLAH>>>.AMOUNT> <UID.<TAG0.IUID<EVAL <LOCAL.BLAH>>>.NAME> (N: <EVAL <LOCAL.BLAH>>)
button 20 <eval (<local._for>*20)+9> 4005 4006 1 0 <eval 6+<local._for>>
ENDIF
ENDFOR
IF !(0<HVAL <TAG.ITEMLIST2>+10> > 10)
button 20 235 4016 4015 0 1 3
ELSE
button 20 235 4016 4015 1 0 6
ENDIF
IF (<exp> > <EVAL <TAG0.ITEMLIST2>+10>)
button 250 235 4005 4006 1 0 5
ENDIF

[DIALOG d_vendor_podprinc BUTTON]
on=0
TAG.ITEMLIST2=0
findid.i_m_vendorfala.remove

ON=1
tag.current=1
sdialog d_vendor_pod1

on=5
TAG.ITEMLIST2 += 10
SDIALOG d_vendor_podprinc 3

ON=6
TAG.ITEMLIST2 -= 10
IF (<TAG.ITEMLIST2> < 1)
TAG.ITEMLIST2=0
SDIALOG d_vendor_podprinc
ELSE
SDIALOG d_vendor_podprinc 3
ENDIF

ON=7 16
tag.current=<HVAL (<argn1>-6)+<tag.itemlist2>>
TAG.ITEMLIST2=0
SDIALOG d_vendor_pod1

//////////////////////////////

[DIALOG d_vendor_pod1]
210, 100
nomove
src.closealldialogs
PAGE 0
gumppic 15 70 04cc
gumppic 140 0 064
LOCAL.TMP=<OBJ>
OBJ=<tag.iuid<EVAL <tag.current>>>
LOCAL.COLOR=<OBJ.COLOR>
IF (<OBJ.COLOR> >= 0775)
LOCAL.COLOR -= 1
ENDIF
OBJ=<LOCAL.TMP>
tilepichue 180 30 <uid.<tag.iuid<eval <tag.current>>>.dispiddec> <eval <local.color>>
dtext 101 129 1152 <uid.<tag.iuid<eval <tag.current>>>.name>
dtext 51 128 102 Nome:
dtext 100 155 1152 <uid.<tag.iuid<eval <tag.current>>>.amount>
dtext 49 154 102 Quant.:
dtext 49 181 102 Preco:
dtext 99 182 1152 <eval <tag.preco<eval <tag.current>>>>gps
dtext 49 210 102 Descricao:
dcroppedtext 115 210 110 110 1152 <QVAL <ISEMPTY <tag.desc<eval <tag.current>>>> ? ...:<tag.desc<eval <tag.current>>>>
IF (<uid.<tag.iuid<eval <tag.current>>>.amount>==1)
button 63 250 249 248 1 0 1
dtext 57 272 32 Comprar Todas
ENDIF
button 341 281 4005 4006 1 0 2
dtext 330 302 32 Proximo
IF (<uid.<tag.iuid<eval <tag.current>>>.amount> > 1)
button 291 125 00d8 00d8 1 0 3
dtext 293 122 88 +
dtext 307 121 55 <eval <tag.currentamount>>
button 271 125 00d8 00d8 1 0 4
dtext 273 122 88 -
button 263 170 249 248 1 0 5
dtext 253 190 59 Comprar Estocado
button 291 145 00d8 00d8 1 0 6
dtext 293 142 32 +
button 271 145 00d8 00d8 1 0 7
dtext 273 142 32 -
ENDIF
IF !(<uid.<tag.iuid<eval <tag.current>>>.type>==t_container)
button 271 220 00d8 00d8 1 0 8
dtext 285 216 39 Ver item
ENDIF
button 35 214 00d8 00d8 1 0 9
button 242 281 4014 4015 1 0 10
dtext 232 302 32 Voltar
IF (<uid.<tag.iuid<eval <tag.current>>>.amount> > 1)
gumppic 52 263 033
dtext 57 272 1152 <eval <tag.preco<eval <tag.current>>>*<tag.currentamount>>
ENDIF
IF (<exp> > 9)
button 341 251 4005 4006 1 0 11
button 242 251 4014 4015 1 0 12
ENDIF
dtext 50 100 033 Item <eval <tag.current>>
IF (<uid.<tag.iuid<eval <tag.current>>>.type>==t_container)
button 271 220 00d8 00d8 1 0 13
dtext 285 216 39 Ver Conteudo
ENDIF

[DIALOG d_vendor_pod1 BUTTON]
On=0
src.dialogclose d_descricao1
findid.i_m_vendorfala.remove

on=1
IF (<distance> > 5)
src.sysmessage @0480 Voce esta longe demais do vendor.
src.dialogclose d_descricao1
findid.i_m_vendorfala.remove
RETURN 1
ENDIF
IF !(0<tag.preco<eval <tag.current>>>)
src.sysmessage @048d Nao ha itens para serem vendidos aqui!
src.dialogclose d_descricao1
findid.i_m_vendorfala.remove
RETURN 1
ENDIF
IF (<uid.<tag.iuid<eval <tag.current>>>.amount> > 1)
src.sysmessage @0483 Esse item devem ser comprado estocadamente!
src.dialogclose d_descricao1
findid.i_m_vendorfala.remove
RETURN 1
ENDIF
IF (<src.totalgold_2> < <tag.preco<eval <tag.current>>>)
say @048d Voce nao tem dinheiro suficiente!
src.dialogclose d_descricao1
findid.i_m_vendorfala.remove
RETURN 1
ENDIF
OBJ=<tag.iuid<eval <tag.current>>>
FOR 10 1
IF (<LOCAL._FOR>!=1)
TRY TAG.LAST<EVAL <LOCAL._FOR>>=<TAG.LAST<EVAL <LOCAL._FOR>-1>>
ELSE
tag.last1=<obj.name> vendido para <src.name>
ENDIF
ENDFOR
local.lastp=<src.p>
local.flags=<src.region.flags>
src.region.flags=0
src.p=1,1
tag.lucrototal += <tag.preco<eval <tag.current>>>
LOCAL.PRECO=<tag.preco<eval <tag.current>>>
tag.money += <tag.preco<eval <tag.current>>>
say @048d <obj.name> vendido para <src.name>!
try tag.preco<eval <tag.current>>
try tag.desc<eval <tag.current>>
obj.cont=<src.findlayer.29>
try tag.iuid<eval <tag.current>>
tag.itensvendidos += 1
src.sysmessage @88 Item posto no seu bank.
tag.current -= 1
src.dialogclose d_descricao1
f_ajeitar_itens
exp -= 1
findid.i_m_vendorfala.remove
src.p=<local.lastp>
src.region.flags=<local.flags>
src.CONSUMEGOLD <LOCAL.PRECO>
src.bankself
src.updatex

on=2
src.dialogclose d_descricao1
IF (<distance> > 5)
src.sysmessage @0480 Voce esta longe demais do vendor.
findid.i_m_vendorfala.remove
RETURN 1
ENDIF
IF !(0<tag.iuid<eval <tag.current>+1>>)
tag.current=1
tag.currentamount=0
sdialog d_vendor_pod1
ELSE
tag.currentamount=0
tag.current += 1
sdialog d_vendor_pod1
ENDIF

on=3
src.dialogclose d_descricao1
IF (<tag.currentamount>==<uid.<tag.iuid<eval <tag.current>>>.amount>)
src.sysmessage @048d Isto e tudo que ele tem para vender!
sdialog d_vendor_pod1
RETURN 1
ENDIF
IF (<tag.currentamount> > <uid.<tag.iuid<eval <tag.current>>>.amount>)
tag.currentamount=<uid.<tag.iuid<eval <tag.current>>>.amount>
sdialog d_vendor_pod1
ELSE
tag.currentamount += 1
sdialog d_vendor_pod1
ENDIF

on=4
IF !(<tag0.currentamount>)
src.sysmessage @048d Voce nao pode comprar -1 item!
sdialog d_vendor_pod1
ELSE
tag.currentamount -= 1
sdialog d_vendor_pod1
ENDIF
src.dialogclose d_descricao1

on=5
IF (<distance> > 5)
src.sysmessage @0480 Voce esta longe demais do vendor.
src.dialogclose d_descricao1
findid.i_m_vendorfala.remove
RETURN 1
ENDIF
IF !(0<tag.preco<eval <tag.current>>>)
src.sysmessage @048d Nao ha itens para serem vendidos aqui!
src.dialogclose d_descricao1
findid.i_m_vendorfala.remove
RETURN 1
ENDIF
IF !(<tag0.currentamount>)
src.sysmessage @0481 Voce nao pode comprar 0 itens!
src.dialogclose d_descricao1
findid.i_m_vendorfala.remove
RETURN 1
ENDIF
IF (<src.totalgold_2> < <HVAL <tag.preco<eval <tag.current>>>*<tag.currentamount>>)
say @048d Voce nao tem dinheiro suficiente!
src.dialogclose d_descricao1
findid.i_m_vendorfala.remove
RETURN 1
ENDIF
OBJ=<tag.iuid<eval <tag.current>>>
local.lastp=<src.p>
local.flags=<src.region.flags>
src.region.flags=0
src.p=1,1
IF (<tag.currentamount>==<obj.amount>)
FOR 10 1
IF (<LOCAL._FOR>!=1)
TRY TAG.LAST<EVAL <LOCAL._FOR>>=<TAG.LAST<EVAL <LOCAL._FOR>-1>>
ELSE
tag.last1=<eval <tag.currentamount>> <obj.name> vendidos para <src.name>
ENDIF
ENDFOR
tag.lucrototal += <tag.preco<eval <tag.current>>>
LOCAL.PRECO=<HVAL <tag.preco<eval <tag.current>>>*<tag.currentamount>>
tag.money += <eval <tag.preco<eval <tag.current>>>*<tag.currentamount>>
say @048d <obj.name> vendido para <src.name>!
try tag.desc<eval <tag.current>>
try tag.preco<eval <tag.current>>
tag.itensvendidos += 1
obj.cont=<src.findlayer.29>
try tag.iuid<eval <tag.current>>
tag.current -= 1
f_ajeitar_itens
exp -= 1
src.sysmessage @88 Item posto no seu bank.
src.dialogclose d_descricao1
findid.i_m_vendorfala.remove
src.p=<local.lastp>
src.region.flags=<local.flags>
src.CONSUMEGOLD <LOCAL.PRECO>
src.bankself
src.updatex
ELSE
FOR 10 1
IF (<LOCAL._FOR>!=1)
TRY TAG.LAST<EVAL <LOCAL._FOR>>=<TAG.LAST<EVAL <LOCAL._FOR>-1>>
ELSE
tag.last1=<eval <tag.currentamount>> <obj.name> vendidos para <src.name>
ENDIF
ENDFOR
tag.lucrototal += <eval <tag.preco<eval <tag.current>>>*<tag.currentamount>>
LOCAL.PRECO=<eval <tag.preco<eval <tag.current>>>*<tag.currentamount>>
tag.money += <local.preco>
serv.newdupe=<obj>
new.amount=<tag.currentamount>
new.cont=<src.findlayer.29>
say @048d <eval <tag.currentamount>> <obj.name> vendidos para <src.name>!
obj.amount -= <tag.currentamount>
src.sysmessage @88 Item posto no seu bank.
src.dialogclose d_descricao1
findid.i_m_vendorfala.remove
src.p=<local.lastp>
src.region.flags=<local.flags>
src.CONSUMEGOLD <LOCAL.PRECO>
src.bankself
src.updatex
ENDIF

on=6
src.dialogclose d_descricao1
IF (<tag.currentamount>==<uid.<tag.iuid<eval <tag.current>>>.amount>)
src.sysmessage @048d Isto e tudo que ele tem para vender!
sdialog d_vendor_pod1
RETURN 1
ENDIF
IF (<eval <tag.currentamount>+10> > <uid.<tag.iuid<eval <tag.current>>>.amount>)
src.sysmessage @048d Voce nao pode comprar mais do que o que ele tem para vender!
sdialog d_vendor_pod1
RETURN 1
ENDIF
IF (<tag.currentamount> > <uid.<tag.iuid<eval <tag.current>>>.amount>)
tag.currentamount=<uid.<tag.iuid<eval <tag.current>>>.amount>
sdialog d_vendor_pod1
ELSE
tag.currentamount += 10
sdialog d_vendor_pod1
ENDIF

on=7
src.dialogclose d_descricao1
IF !(<tag0.currentamount>)
src.sysmessage @048d Voce nao pode comprar -10 itens!
sdialog d_vendor_pod1
RETURN 1
ENDIF
IF (<eval <tag.currentamount>-10> < 0)
src.sysmessage @048d Voce nao pode comprar -1 item!
sdialog d_vendor_pod1
RETURN 1
ENDIF
tag.currentamount -= 10
sdialog d_vendor_pod1

on=8
IF !(<tag0.iuid<eval <tag.current>>>)
src.sysmessage @0480 Nao ha itens nesse slot.
sdialog d_vendor_pod1
ELSE
findid.i_bagdeitens.empty
serv.newdupe <tag.iuid<eval <tag.current>>>
new.attr=attr_move_never|attr_identIFied
new.cont=<findid.i_bagdeitens>
findid.i_bagdeitens.open
sdialog d_vendor_pod1
ENDIF
src.dialogclose d_descricao1

on=9
IF !(strcmpi(<src.memoryfindtype.memory_gumprecord.tag.dialog_name>,d_descricao1))
src.dialogclose d_descricao1
sdialog d_vendor_pod1
tag.algarismo2=0
ELSE
tag.algarismo2=<tag.current>
sdialog d_vendor_pod1
sdialog d_descricao1
ENDIF

ON=10
tag.currentamount=0
tag.algarismo2=0
src.dialogclose d_descricao1
IF (<tag.current>==1)
tag.current=<exp>
sdialog d_vendor_pod1
ELSE
tag.current -= 1
sdialog d_vendor_pod1
ENDIF

on=11
IF (<distance> > 5)
src.sysmessage @0480 Voce esta longe demais do vendor.
findid.i_m_vendorfala.remove
ELIF !(0<tag.iuid<eval <tag.current>+10>>)
tag.currentamount=0
tag.current=<exp>
sdialog d_vendor_pod1
ELSE
tag.currentamount=0
tag.current += 10
sdialog d_vendor_pod1
ENDIF
src.dialogclose d_descricao1

ON=12
tag.currentamount=0
tag.algarismo2=0
src.dialogclose d_descricao1
IF (<tag0.iuid<eval <tag.current>-10>> < 1)
tag.current=1
sdialog d_vendor_pod1
ELSE
tag.current -= 10
sdialog d_vendor_pod1
ENDIF

on=13
IF !(0<tag.iuid<eval <tag.current>>>)
src.sysmessage @0480 Nao ha itens nesse slot.
sdialog d_vendor_pod1
ELSE
findid.i_bagdeitens.empty
serv.newdupe <tag.iuid<eval <tag.current>>>
new.attr=attr_move_never
new.cont=<findid.i_bagdeitens>
new.open
FORCONT <new> 999
attr=attr_move_never
IF (<type>==t_container)
OPEN
ENDIF
ENDFOR
sdialog d_vendor_pod1
ENDIF
src.dialogclose d_descricao1

////////////////////////////

[itemdef i_bagdeitens]
NAME=bag de teste
ID=i_chest_metal
TYPE=t_container
WEIGHT=0

on=@create
color=0480
attr=attr_move_never

/////////////////

[DIALOG d_descricao1]
0,260
nomove
PAGE 0
resizepic 45 60 2620 210 205
dhtmlgump 51 70 197 185 1 200 <DEF.BFONT_DGRAY><DEF.CENTER>Descricao de <uid.<tag.iuid<eval <tag.algarismo2>>>.name> :<DEF.CENTERE> <DEF.BFONT_BLUE><QVAL <ISEMPTY <tag.desc<eval <tag.algarismo2>>>> ? ...:<tag.desc<eval <tag.algarismo2>>>>
button 245 54 00d8 00d8 1 0 1
dtext 247 51 88 -

[DIALOG d_descricao1 BUTTON]
ON=0
tag.algarismo2=0

ON=1
tag.algarismo2=0

///////////////////////

[DIALOG d_lastvendor]
210, 100
src.closealldialogs
PAGE 0
resizepic 20 60 3500 310 300
dtext 100 70 035 Ultimas Vendas
FOR 10
dtext 40 <eval (<local._for>*20)+80> 1152 <tag0.last<eval <local._for>>>
ENDFOR
button 242 321 4014 4015 1 0 1

[DIALOG d_lastvendor BUTTON]
on=0
findid.i_m_vendorfala.remove

on=1
sdialog d_caracteristicas_vendor

///////////////////////

[function f_ajeitar_itens]
local.itotal=<exp>
local.item=<eval <tag.current>+1>
FOR <eval <local.itotal>-<local.item>>
try tag.iuid<eval <local.item>>=<tag.iuid<eval <local.item>+1>>
try tag.desc<eval <local.item>>=<tag0.desc<eval <local.item>+1>>
IF (<ISEMPTY <TAG.DESC<eval <local.item>+1>>>)
try tag.desc<eval <local.item>>
ENDIF
try tag.preco<eval <local.item>>=<tag.preco<eval <local.item>+1>>
local.item += 1
ENDFOR
try tag.iuid<eval <local.itotal>>
try tag.desc<eval <local.itotal>>
try tag.preco<eval <local.itotal>>

//////////////////////////

[function f_retirar_itens]
IF (<exp>)
local.itotais=<exp>
local.item=1
FOR <local.itotais>
try uid.<tag.iuid<eval <local.item>>>.cont=<argn1>
try tag.iuid<eval <local.item>>
try tag.desc<eval <local.item>>
try tag.preco<eval <local.item>>
local.item += 1
ENDFOR
ENDIF

////////////////////////

[FUNCTION vendorcheck]
EVENTS e_vendorcheck
TRIGGER @TEST
LOCAL.TMP <NEW.TAG.RET>
REMOVE
RETURN <LOCAL.TMP>

[TYPEDEF e_vendorcheck]
ON=@TEST
LOCAL.LINK=<LINK>
FORCHARS 3
IF (<LOCAL.LINK>!=<UID>) && (<BASEID>==c_vendor_pod)
NEW.TAG.RET 1
RETURN 1
ENDIF
ENDFOR
NEW.TAG.RET 0

///////////////////////

[function f_players_perto]
IF (<findid.i_m_vendorfala.timer>==-1)
findid.i_m_vendorfala.remove
RETURN 0
ELIF !(<uid.<findid.i_m_vendorfala.tag.player>.isonline>)
findid.i_m_vendorfala.remove
RETURN 0
ELIF (<uid.<findid.i_m_vendorfala.tag.player>.distance> > 5)
try uid.<findid.i_m_vendorfala.tag.player>.sysmessage Voce estava longe demais do Vendor e <src.name> pode acessa-lo.
findid.i_m_vendorfala.timer
serv.newitem=i_m_vendorfala,1,<uid>
new.timer=360
new.tag.player=<src>
RETURN 0
ELIF (<findid.i_m_vendorfala>)
RETURN 1
ELSE
RETURN 0
ENDIF

////////////////////

[itemdef i_m_vendorfala]
name=vendor fala mem
id=i_memory
type=t_eq_script
layer=layer_special

on=@create
attr=attr_invis|attr_decay

on=@timer
try uid.<tag.player>.findid.i_memory_ivendor.remove
trysrc <tag.player> src.dialogclose d_vendor_owner_pod
trysrc <tag.player> src.dialogclose d_caracteristicas_vendor
trysrc <tag.player> src.dialogclose d_descricao1
trysrc <tag.player> src.dialogclose d_vendor_price1
trysrc <tag.player> src.dialogclose d_remover_item1
trysrc <tag.player> src.dialogclose d_vendor_pod1
trysrc <tag.player> src.dialogclose d_vendor_podprinc
trysrc <tag.player> src.dialogclose d_lastvendor
trysrc <tag.player> src.dialogclose d_mudarcor_vendor
trysrc <tag.player> src.dialogclose d_mudardesc1
trysrc <tag.player> src.dialogclose d_mudarnome_vendor
trysrc <tag.player> src.dialogclose d_mudarfala_vendor
remove
RETURN 1

//////////////////

[itemdef i_m_falas]
name=memory falas
id=i_memory
layer=layer_special
type=t_eq_script
weight=0

on=@create
attr=attr_invis

/////////////////

[FUNCTION addgold]
LOCAL.AMOUNT=<ARGN1>
WHILE <LOCAL.AMOUNT>
IF (<LOCAL.AMOUNT> >= 65000)
SERV.NEWITEM i_gold,65000
LOCAL.AMOUNT -= 65000
ELSE
SERV.NEWITEM i_gold,<LOCAL.AMOUNT>
LOCAL.AMOUNT=0
ENDIF
IF (0<ARGN2>)
NEW.CONT <ARGN2>
ELSE
BOUNCE <NEW>
ENDIF
ENDWHILE

[PLEVEL 4]
addgold

//////////////////////

[ITEMDEF i_m_vendortimer]
ID=i_memory
NAME=Vendor Timer
TYPE=t_eq_script

ON=@Create
ATTR=ATTR_INVIS|ATTR_DECAY

ON=@Timer
IF (<CONT.exp>)
serv.newitem=i_backpack
new.name=Vendor Bag
new.color=39
IF (<UID.<CONT.level>.ISPLAYER>)
new.cont=<uid.<CONT.level>.findlayer.29>
ELSE
new.p=1,1
new.attr=attr_decay
new.timer 1
ENDIF
f_retirar_itens <new>
ENDIF
IF (<CONT.TAG0.MONEY>)
local.tax=<eval (<CONT.tag.money>*5)/100>
CONT.tag.money -= <local.tax>
IF (<UID.<CONT.level>.ISPLAYER>)
addgold <CONT.tag.money> <UID.<CONT.level>.findlayer.29>
ENDIF
CONT.tag.money=0
ENDIF
IF (<UID.<CONT.level>.ISPLAYER>)
try uid.<CONT.level>.sysmessage Vendor deletado.
try uid.<CONT.level>.consumegold 5000
serv.newitem=i_deed_vendor,1,<uid.<cont.level>.findlayer.21>
try uid.<level>.account.tag.vendedores
ENDIF
IF (<cont.findid.i_m_vendorfala>)
findid.i_m_vendorfala.trigger @timer
ENDIF
CONT.REMOVE
RETURN 1

[EOF]