// Script de healing by SoloYo

[ITEMDEF 0e21]
DEFNAME=i_bandage
RESOURCES=i_cloth
TYPE=T_BANDAGE
WEIGHT=.1
DUPELIST=0ee9
CATEGORY=Items by Professions
SUBSECTION=Healer
DESCRIPTION=Clean Bandages

ON=@DCLICK
IF (<SRC.FINDID(i_mem_healing).UID> == 0)
 TARGETG Quem voce gostaria de curar?
 RETURN 1

ELSE
 IF (<SRC.FINDID(i_mem_healing).TIMER> = -1)
  SRC.FINDID(i_mem_healing).REMOVE
 ENDIF
 SRC.SYSMESSAGE Voce esta ocupado.
 RETURN 1
ENDIF

ON=@TARGON_ITEM
IF (<SRC.TARG.TYPE>==T_CORPSE)
	IF !(<SRC.RESTEST 30 I_BANDAGE>)
		SRC.SYSMESSAGE Voce precisa de 30 bandagens para ressar o alguem
		return 1 
	ENDIF

	IF !(<SRC.TARG.CANSEELOS>) || (<src.targ.distance>>2)
		src.sysmessage Voce esta muito longe do corpo
		return 1
	endif

	IF (<SRC.HEALING> < 800) || (<SRC.ANATOMY> < 800)
		SRC.SYSMESSAGE Voce nao tem skill suficiente para ressar este player
		return 1 
	ENDIF
			
	IF (<REGION.FLAGS> & region_flag_nodecay) || (<REGION.FLAGS> & region_flag_safe)
		SRC.SYSMESSAGE Voce nao pode resucitar ninguem neste local
		RETURN 1
	ENDIF
	
	OBJ <SRC.UID>
	LOCAL.NAME=<SRC.TARG.NAME>
	FORCHARS 4
		IF (STRMATCH(*<NAME>*,*<LOCAL.NAME>*))
			obj.sysmessage Voce esta tentando resucitar <name>
			LOCAL.ACHOU 1
			LOCAL.UID <UID>
			LOCAL.PX <P.X>
			LOCAL.PY <P.Y>
		ENDIF
	ENDFOR

	IF <LOCAL.ACHOU>>0
		SRC.CONSUME 30 I_BANDAGE
		SERV.NEWITEM=i_bandage_bloody 
		NEW.AMOUNT 30 
		NEW.BOUNCE

		SERV.NEWITEM=i_mem_healing
		NEW.TAG.EUX=<SRC.P.X>
		NEW.TAG.TEMPO=3
		NEW.TAG.EUY=<SRC.P.Y>
		NEW.TAG.ELEX=<LOCAL.PX>
		NEW.TAG.ELEY=<LOCAL.PY>
		NEW.TAG.UID=<LOCAL.UID>
		NEW.TAG.RESUCITAR=1
		NEW.TAG.HEAL=0
		NEW.TAG.PET=0
		NEW.EQUIP
		return 1
	else
		SRC.SYSMESSAGE Nao tem nenhuma alma por perto
		return 1
	endif
return 1
ENDIF

 IF <SRC.TARG.CANSEELOS>
  IF (<SRC.TARG.TYPE>==t_water)||(<SRC.TARG.TYPE>==t_water_wash)
   RETURN 0
  ENDIF
 ENDIF
 SRC.SYSMESSAGE Voce so pode usar bandage em seres vivos!
RETURN 1

ON=@TARGON_GROUND
 SRC.SYSMESSAGE Voce so pode usar bandage em seres vivos!
RETURN 1

ON=@TARGON_CHAR
IF !(<SRC.RESTEST 1 i_bandage>)
 SRC.SYSMESSAGE A bandage tem que estar na sua bag!
 RETURN 1
ENDIF

IF !<SRC.TARG.CANSEELOS>
 SRC.SYSMESSAGE <SRC.TARG.NAME> esta muito distante.
 RETURN 1
ENDIF

IF !((<SRC.TARG.NPC> == brain_none) || (<SRC.TARG.NPC> == brain_animal))
 SRC.SYSMESSAGE Voce nao pode usar bandagem nisso!
 RETURN 1
ENDIF

IF (<SRC.TARG.DISTANCE> > 3)
 SRC.SYSMESSAGE <SRC.TARG.NAME> esta muito distante.
 SRC.TARG.SYSMESSAGE <SRC.NAME> Tentou aplicar as Bandagens, mais voce esta muito longe!
 RETURN 1
ENDIF

IF (<SRC.TARG.NPC>==BRAIN_UNDEAD)
 SRC.SYSMESSAGE="You can not heal the undead."
 RETURN 1
ENDIF

IF (<SRC.TARG.HITPOINTS> >= <SRC.TARG.STR>)
  SRC.SYSMESSAGE <SRC.TARG.NAME> nao precisa de curamentos.
  RETURN 1
ENDIF

IF (<SRC.FLAGS> & statf_poisoned)
 SRC.SYSMESSAGE Voce nao pode curar poison.
 RETURN 1
ENDIF

IF (<SRC.FINDLAYER(layer_hand1).UID> != 0)
 SRC.FINDLAYER(layer_hand1).UNEQUIP
ENDIF
IF (<SRC.FINDLAYER(layer_hand2).UID> != 0)
 SRC.FINDLAYER(layer_hand2).UNEQUIP
ENDIF

IF ((<SRC.TARG.KILLS> > <SERV.MURDERMINCOUNT>) || (<SRC.TARG.FLAGS> & statf_criminal))
 IF (<SRC.TARG.SERIAL> != <SRC.SERIAL>)
  IF !(<SRC.KILLS> > 0) && (<SRC.TARG.FLAGS> & statf_criminal)
   SRC.CRIMINAL
  ENDIF
 ENDIF
ENDIF

IF (<SRC.TARG.FLAGS> & statf_dead)
  SRC.SYSMESSAGE Use as bandagens no corpo.
  RETURN 1
ENDIF

IF (<SRC.TARG.NPC> == brain_none)
 IF ( <SRC.TARG.SERIAL> != <SRC.SERIAL> )
  SRC.SYSMESSAGE Voce aplicou bandage em <SRC.TARG.NAME>
  SRC.TARG.SYSMESSAGE <SRC.NAME> aplicou bandage em voce...
 ELSE
  SRC.SYSMESSAGE Voce comeca a curar...
 ENDIF

 SERV.NEWITEM=i_mem_healing
 NEW.LINK=<SRC.TARG.SERIAL>
 NEW.TAG.TEMPO=3
 NEW.TAG.LINKX=<SRC.TARG.P.X>
 NEW.TAG.LINKY=<SRC.TARG.P.Y>
 NEW.TAG.CONTX=<SRC.P.X>
 NEW.TAG.CONTY=<SRC.P.Y>
 NEW.TAG.RESUCITAR=0
 NEW.TAG.HEAL=<EVAL( {(((<SRC.Anatomy> + <SRC.Healing>) / 100)) (((<SRC.Anatomy> + <SRC.Healing>) / 50))} )>
 NEW.TAG.PET=0
 NEW.EQUIP

 RETURN 1
ENDIF

IF (<SRC.TARG.NPC> == brain_animal)

 SRC.SYSMESSAGE Voce aplicou bandage em <SRC.TARG.NAME>.

 SERV.NEWITEM=i_mem_healing
 NEW.LINK=<SRC.TARG.SERIAL>
 NEW.TAG.TEMPO=3
 NEW.TAG.LINKX=<SRC.TARG.P.X>
 NEW.TAG.LINKY=<SRC.TARG.P.Y>
 NEW.TAG.CONTX=<SRC.P.X>
 NEW.TAG.CONTY=<SRC.P.Y>
 NEW.TAG.RESUCITAR=0
 NEW.TAG.HEAL=<EVAL( {(((<SRC.ANIMALLORE> + <SRC.VETERINARY>) / 100) + 10) (((<SRC.ANIMALLORE> + <SRC.VETERINARY>) / 50) + 20)} )>
 NEW.TAG.PET=1
 NEW.EQUIP

 RETURN 1
ENDIF
RETURN 1

[ITEMDEF i_mem_healing]
ID=i_memory
TYPE=t_eq_script
NAME=curacion

ON=@EQUIP
TIMER=<TAG.TEMPO>
ATTR=attr_decay

ON=@TIMER

IF (RAND(20) == 0)
 CONT.SYSMESSAGE Voce perdeu a concentracao.
 REMOVE
 RETURN 1
ENDIF

IF (<TAG.RESUCITAR> == 1)

	IF !(<TAG.EUX>==<CONT.P.X>) || !(<TAG.EUY>==<CONT.P.Y>)
		CONT.SYSMESSAGE Voce se mecheu e perdeu a concentracao...
		return 1
	endif

	OBJ <TAG.UID>

	IF !(<OBJ.FLAGS> & statf_dead)
		CONT.SYSMESSAGE Seu alvo ja foi resucitado...
		RETURN 1
	ENDIF

	IF !(<TAG.ELEX>==<OBJ.P.X>) || !(<TAG.ELEY>==<OBJ.P.Y>)
		CONT.SYSMESSAGE O seu alvo se mecheu e voce perdeu a concentracao...
		return 1
	endif

obj.resurrect
obj.sysmessage <cont.name> te resucitou...
cont.sysmessage Voce resucitou <obj.name>
cont.FINDID(i_mem_healing).REMOVE
return 1
ENDIF

IF (<LINK.FLAGS> & statf_poisoned)
 CONT.SYSMESSAGE Voce nao pode curar poison.
 REMOVE
 RETURN 1
ENDIF

IF (<LINK.HITS> >= <LINK.STR>)
 REMOVE
 RETURN 1
ENDIF

IF (<LINK.FLAGS> & statf_dead)
 REMOVE
 RETURN 1
ENDIF

IF (<TAG.PET> == 1)
 IF <CONT.veterinary> < 1000
  CONT.custom_skillgain
  CONT.veterinary += 1
 ENDIF
ELSE
 IF <CONT.healing> < 1000
  CONT.custom_skillgain
  CONT.healing += 1
 ENDIF
ENDIF

CONT.CONSUME 1 i_bandage

SERV.NEWITEM=i_bandage_bloody
NEW.CONT <CONT.UID>

TAG.HITS=<LINK.HITS> + <TAG.HEAL>

IF (<TAG.HITS> > <LINK.STR>)
 TAG.HITS = <LINK.STR>
ENDIF

CONT.SYSMESSAGE Voce curou <EVAL(<TAG.HITS> - <LINK.HITS>)> hits de <LINK.NAME>.
LINK.HITS = <TAG.HITS>
LINK.EFFECT=3,i_FX_bless_effect,0,14,1

REMOVE
RETURN 1

[ITEMDEF 0ee9]
//clean bandages
DUPEITEM=0e21

[EOF]